From ee1786edd7972f9ff55fc8abb90a6d981d66998e Mon Sep 17 00:00:00 2001
From: Adrian Kummerlaender
Date: Fri, 24 Oct 2014 18:59:25 +0200
Subject: Added timeline ATOM feed and removed XHTML target * moved repository
 feeds to `repository` directory * replaced paginated XHTML timeline target
 with and ATOM feed ** removed `paginated_timeline.xsl` transformation
 including the `04_meta` level ** removed CSS and master stylesheets * added
 title, url and commit count meta data to `meta.xml` * expanded ATOM feed URLs
 * timeline feed has an upper limit of `commit_count` items ** repository
 feeds have the same limit because only `commit_count` commits of every
 repository are fetched in the first place

---
 source/99_result/repository/atom.xsl | 81 ++++++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)
 create mode 100644 source/99_result/repository/atom.xsl

(limited to 'source/99_result/repository/atom.xsl')

diff --git a/source/99_result/repository/atom.xsl b/source/99_result/repository/atom.xsl
new file mode 100644
index 0000000..f858dea
--- /dev/null
+++ b/source/99_result/repository/atom.xsl
@@ -0,0 +1,81 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<xsl:stylesheet
+	version="1.0"
+	xmlns="http://www.w3.org/2005/Atom"
+	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+>
+
+<xsl:output
+	method="xml"
+	omit-xml-declaration="no"
+	encoding="UTF-8"
+	indent="no"
+/>
+
+<xsl:include href="[utility/xhtml.xsl]"/>
+
+<xsl:variable name="meta">
+	<datasource type="main"    mode="iterate" source="02_augment/commits.xml" target="repository"/>
+	<datasource type="support" mode="full"    source="00_content/meta.xml"    target="meta"/>
+	<target     mode="xpath"   value="concat($datasource/repository/entry/@handle, '.xml')"/>
+</xsl:variable>
+
+<xsl:variable name="root"   select="/datasource"/>
+<xsl:variable name="title"  select="datasource/repository/entry/@handle"/>
+<xsl:variable name="url"    select="concat($root/meta/url, '/feed/', $title, '.xml')"/>
+<xsl:variable name="latest" select="repository/entry/commit[1]"/>
+
+<xsl:template match="datasource">
+	<feed>
+		<link href="{$url}" rel="self" title="{$title}" type="application/atom+xml"/>
+
+		<id>
+			<xsl:value-of select="$url"/>
+		</id>
+		<title>
+			<xsl:value-of select="$title"/>
+		</title>
+		<updated>
+			<xsl:value-of select="$latest/date"/>
+			<xsl:text>T</xsl:text>
+			<xsl:value-of select="$latest/date/@time"/>
+			<xsl:text>:00+02:00</xsl:text>
+		</updated>
+
+		<xsl:apply-templates select="repository/entry/commit"/>
+	</feed>
+</xsl:template>
+
+<xsl:template match="repository/entry/commit">
+	<entry xmlns="http://www.w3.org/2005/Atom">
+		<id>
+			<xsl:value-of select="@hash"/>
+		</id>
+		<title>
+			<xsl:value-of select="message/h1"/>
+		</title>
+		<link rel="alternate" title="{@hash}">
+			<xsl:attribute name="href">
+				<xsl:value-of select="concat(
+					$root/meta/mirror/repository, '/',
+					../@handle,                   '/',
+					$root/meta/mirror/commit,
+					@hash
+				)"/>
+			</xsl:attribute>
+		</link>
+		<content type="xhtml">
+			<div xmlns="http://www.w3.org/1999/xhtml">
+				<xsl:apply-templates select="message/*[name() != 'h1']" mode="xhtml"/>
+			</div>
+		</content>
+		<updated>
+			<xsl:value-of select="date"/>
+			<xsl:text>T</xsl:text>
+			<xsl:value-of select="date/@time"/>
+			<xsl:text>:00+02:00</xsl:text>
+		</updated>
+	</entry>
+</xsl:template>
+
+</xsl:stylesheet>
-- 
cgit v1.2.3