From 4804893a6616a312ac8028e42d2aa990018ffbe6 Mon Sep 17 00:00:00 2001
From: Adrian Kummerlaender
Date: Wed, 12 Apr 2017 16:58:18 +0200
Subject: Modularize primitives implementation, add stack manipulators

---
 src/primitives/eval.d |  48 ++++++++++++++++++++
 src/primitives/impl.d | 119 ++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 167 insertions(+)
 create mode 100644 src/primitives/eval.d
 create mode 100644 src/primitives/impl.d

(limited to 'src/primitives')

diff --git a/src/primitives/eval.d b/src/primitives/eval.d
new file mode 100644
index 0000000..3f91e80
--- /dev/null
+++ b/src/primitives/eval.d
@@ -0,0 +1,48 @@
+module src.primitives.eval;
+
+import src.primitives.impl;
+
+bool evaluate(int value) {
+	return drop_mode;
+}
+
+bool evaluate(string word) {
+	if ( drop_mode ) {
+		if ( word == "then" ) {
+			return conditional_end;
+		} else {
+			return true;
+		}
+	}
+
+	switch ( word ) {
+		case "§":
+			return definition_start;
+		case "$":
+			return binary_op_variable_bind;
+		case "@":
+			return unary_op_variable_resolve;
+		case "if":
+			return conditional_start;
+		case "then":
+			return conditional_end;
+		case "+":
+			return binary_op_add;
+		case "*":
+			return binary_op_multiply;
+		case "/":
+			return binary_op_divide;
+		case "%":
+			return binary_op_modulo;
+		case ".":
+			return unary_op_io_print;
+		case "pop":
+			return unary_op_stack_pop;
+		case "dup":
+			return unary_op_stack_dup;
+		case "swp":
+			return binary_op_stack_swp;
+		default:
+			return false;
+	}
+}
diff --git a/src/primitives/impl.d b/src/primitives/impl.d
new file mode 100644
index 0000000..4ec9019
--- /dev/null
+++ b/src/primitives/impl.d
@@ -0,0 +1,119 @@
+module src.primitives.impl;
+
+import std.stdio;
+
+import src.stack;
+import src.definition;
+
+int[string] variables;
+bool        drop_mode;
+
+bool definition_start() {
+	src.definition.start;
+	return true;
+}
+
+bool binary_op_variable_bind() {
+	string name  = stack.pop.get!string;
+	int    value = stack.pop.get!int;
+
+	variables[name] = value;
+	return true;
+}
+
+bool unary_op_variable_resolve() {
+	string name = stack.pop.get!string;
+
+	if ( name in variables ) {
+		stack.push(variables[name]);
+	}
+
+	return true;
+}
+
+bool conditional_start() {
+	switch ( stack.pop.get!int ) {
+		case 0:
+			drop_mode = true;
+			return true;
+		case 1:
+			drop_mode = false;
+			return true;
+		default:
+			throw new Exception("invalid logic value");
+	}
+}
+
+bool conditional_end() {
+	drop_mode = false;
+	return true;
+}
+
+bool binary_op_add() {
+	int b = stack.pop.get!int;
+	int a = stack.pop.get!int;
+
+	stack.push(a + b);
+
+	return true;
+}
+
+bool binary_op_multiply() {
+	int b = stack.pop.get!int;
+	int a = stack.pop.get!int;
+
+	stack.push(a * b);
+
+	return true;
+}
+
+bool binary_op_divide() {
+	int b = stack.pop.get!int;
+	int a = stack.pop.get!int;
+
+	if ( b == 0 ) {
+		throw new Exception("division by 0 undefined");
+	} else {
+		stack.push(a / b);
+	}
+
+	return true;
+}
+
+bool binary_op_modulo() {
+	int b = stack.pop.get!int;
+	int a = stack.pop.get!int;
+
+	if ( b == 0 ) {
+		throw new Exception("modulo 0 undefined");
+	} else {
+		stack.push(a % b);
+	}
+
+	return true;
+}
+
+bool unary_op_io_print() {
+	writeln(stack.top);
+	return true;
+}
+
+bool unary_op_stack_pop() {
+	stack.pop;
+	return true;
+}
+
+bool unary_op_stack_dup() {
+	stack.push(stack.top);
+	return true;
+}
+
+bool binary_op_stack_swp() {
+	auto b = stack.pop;
+	auto a = stack.pop;
+
+	stack.push(b);
+	stack.push(a);
+
+	return true;
+}
-- 
cgit v1.2.3