aboutsummaryrefslogtreecommitdiff
path: root/qml/EmbeddedTerminal.qml
blob: 6d0dc6ede3b52b1007d776ae97f104934d4c396f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
import QtQuick 2.0
import QMLTermWidget 1.0
import QtQuick.Layouts 1.1
import Qt.labs.settings 1.0

Item {
	id: item

	property string program
	property string workingDirectory

	Settings {
		id: settings
		category: "terminal"

		property int    initialLines      : 20
		property int    frameWidth        : 10
		property int    fontSize          : 8
		property string fontFamily        : "Monospace"
		property string colorScheme       : "cool-retro-term"
		property string overlayBackground : "black"
		property string overlayFontColor  : "white"
	}

	property int lines : settings.initialLines

	height: terminal.height
	width:  parent.width - settings.frameWidth

	function select()         { highlighter.select()     }
	function deselect()       { highlighter.deselect()   }
	function displayOverlay() { overlay.displayBriefly() }

	RowLayout {
		id: container

		anchors {
			left:  parent.left
			right: parent.right
		}

		spacing: 0

		Highlighter {
			id: highlighter

			width: settings.frameWidth
			Layout.fillHeight: true
		}

		QMLTermWidget {
			id: terminal

			font {
				family:    settings.fontFamily
				pointSize: settings.fontSize
			}

			Layout.fillWidth:       true
			Layout.preferredHeight: fontMetrics.height * item.lines

			colorScheme: settings.colorScheme

			session: QMLTermSession {
				initialWorkingDirectory: item.workingDirectory

				shellProgram: {
					return (item.program).split(" ")[0];
				}

				shellProgramArgs: {
					const elements = (item.program).split(" ");
					elements.shift();

					return elements;
				}
			}

			Component.onCompleted: {
				forceActiveFocus();
				highlighter.select();
				session.startShellProgram();
				overlay.enabled = true;
			}

			onTermGetFocus:  highlighter.focus()
			onTermLostFocus: highlighter.unfocus()
			onHeightChanged: overlay.displayBriefly();
			onWidthChanged:  overlay.displayBriefly();

			Rectangle {
				id: overlay

				property bool enabled : false

				function displayBriefly() {
					if ( enabled ) { animation.restart() }
				}

				anchors.fill: parent
				opacity: 0
				color: settings.overlayBackground

				SequentialAnimation {
					id: animation

					ScriptAction {
						script: overlay.opacity = 0.8
					}

					PauseAnimation {
						duration: 500
					}

					NumberAnimation {
						target:   overlay
						property: "opacity"

						easing.type: Easing.InSine
						duration: 300
						from:     0.8
						to:       0
					}
				}

				Text {
					anchors {
						horizontalCenter: overlay.horizontalCenter
						verticalCenter:   overlay.verticalCenter
					}

					font {
						family:    settings.fontFamily
						pointSize: settings.fontSize * 2
					}
					color: settings.overlayFontColor

					text: {
						return item.lines
						     + 'x'
						     + Math.floor(terminal.width / terminal.fontMetrics.width);
					}
				}
			}

			MouseArea {
				anchors.fill: parent
				acceptedButtons: Qt.NoButton
				onWheel: { }
			}
		}
	}
}