src/command/CommandInput.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142

import QtQuick 2.0
import QtQuick.Layouts 1.1

import "commands.js" as Commands

Item {
	id: item

	signal executed

	function focus(prefix) {
		visible      = true;
		command.text = prefix;
		command.forceActiveFocus();
	}

	function unfocus() {
		visible = false;
	}

	visible: false

	Layout.preferredHeight: container.height

	onVisibleChanged: container.reset()

	Rectangle {
		anchors {
			top:   parent.top
			left:  parent.left
			right: parent.right
		}

		height: container.height

		color: settings.command.background

		ColumnLayout {
			id: container

			function reset() {
				command.initialize();
				output.initialize();
			}

			TextInput {
				id: command

				Layout.fillWidth: true

				font {
					family:    settings.command.fontFamily
					pointSize: settings.command.fontSize
				}

				color:             settings.command.fontColor
				selectionColor:    settings.command.fontColor
				selectedTextColor: settings.command.background
				selectByMouse:     true

				function initialize() {
					text = '';
				}

				onAccepted: {
					output.initialize();

					const prefix = String(text).charAt(0);
					const cmd    = String(text).substring(1, String(text).length);

					switch ( prefix ) {
						case ':': {
							Commands.execute(output, cmd);
							break;
						}
						default: {
							output.error('"' + prefix + '"' + ' is not a command prefix.');
						}
					}

					if ( output.isInitial() ) {
						item.executed();
					}
				}
			}

			TextEdit {
				id: output

				Layout.fillWidth:       true
				Layout.preferredHeight: 0

				font {
					family:    settings.command.fontFamily
					pointSize: settings.command.fontSize
				}

				color:             settings.command.fontColor
				selectionColor:    settings.command.fontColor
				selectedTextColor: settings.command.background

				selectByMouse: true
				readOnly:      true

				textFormat: TextEdit.RichText
				wrapMode:   TextEdit.NoWrap

				function isInitial() {
					return length === 0;
				}

				function initialize() {
					text = '';
				}

				function log(msg) {
					if ( isInitial() ) {
						text = msg;
					} else {
						text += '\n' + msg;
					}
				}

				function error(msg) {
					text = '<i><font color="'
					     + settings.command.errorColor
					     + '">'
					     + msg
					     + '</font></i>';
				}

				onTextChanged: {
					if ( isInitial() ) {
						Layout.preferredHeight = 0;
					} else {
						Layout.preferredHeight = contentHeight;
					}
				}
			}
		}
	}
}