aboutsummaryrefslogtreecommitdiff
path: root/source/99_result/overview.xsl
blob: ace36f1df3752cabe8d5ae40cc43d9792eabea4e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
	version="1.0"
	xmlns="http://www.w3.org/1999/xhtml"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>

<xsl:output
	method="xml"
	doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN"
	doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd"
	omit-xml-declaration="yes"
	encoding="UTF-8"
	indent="no"
/>

<xsl:include href="[utility/xhtml.xsl]"/>
<xsl:include href="[utility/date-time.xsl]"/>

<xsl:variable name="meta">
	<datasource type="main"    mode="full" source="00_content/meta.xml"      target="meta"/>
	<datasource type="support" mode="full" source="02_augment/articles.xml"  target="articles"/>
	<datasource type="support" mode="full" source="00_content/blip_feed.xml" target="timeline"/>
	<target     mode="plain"   value="index.html"/>
</xsl:variable>

<xsl:variable name="root" select="/datasource"/>

<xsl:template match="articles/entry">
	<h3>
		<span class="arrow">
			<xsl:text>» </xsl:text>
		</span>
		<a href="{link}">
			<xsl:value-of select="title"/>
		</a>
	</h3>

	<span class="info">
		<xsl:call-template name="format-date">
			<xsl:with-param name="date" select="date"/>
			<xsl:with-param name="format" select="'M x, Y'"/>
		</xsl:call-template>
		<xsl:text> | </xsl:text>
		<xsl:value-of select="author"/>
	</span>

	<p>
		<xsl:apply-templates select="content/node()" mode="xhtml"/>
		<xsl:text> </xsl:text>

		<a class="more" href="{link}">
			<xsl:text></xsl:text>
		</a>
	</p>
</xsl:template>

<xsl:template match="timeline/entry[@type='commit']">
	<h3>
		<span class="arrow">
			<xsl:text>» </xsl:text>
		</span>
		<a href="{$root/meta/repository_base}/{@repo}/commit/?id={@hash}">
			<xsl:value-of select="title"/>
		</a>
	</h3>

	<span class="info">
		<xsl:call-template name="format-date">
			<xsl:with-param name="date" select="date"/>
			<xsl:with-param name="format" select="'M x, Y'"/>
		</xsl:call-template>
		<xsl:text> at </xsl:text>
			<xsl:value-of select="date/@time"/>
		<xsl:text> | </xsl:text>
		<a href="{$root/meta/repository_base}/{@repo}/">
			<xsl:value-of select="@repo"/>
		</a>
		<xsl:text> | </xsl:text>
		<a href="{$root/meta/repository_base}/{@repo}/commit/?id={@hash}">
			<xsl:value-of select="substring(@hash,0,7)"/>
		</a>
		<xsl:text> | </xsl:text>
		<xsl:value-of select="$root/meta/author"/>
	</span>

	<xsl:apply-templates select="content/node()" mode="xhtml"/>
</xsl:template>

<xsl:template match="timeline/entry[@type='unstructured']">
	<h3>
		<span class="arrow">
			<xsl:text>» </xsl:text>
		</span>
		<a href="{title/@href}">
			<xsl:value-of select="title"/>
		</a>
	</h3>

	<span class="info">
		<xsl:call-template name="format-date">
			<xsl:with-param name="date" select="date"/>
			<xsl:with-param name="format" select="'M x, Y'"/>
		</xsl:call-template>
		<xsl:text> at </xsl:text>
			<xsl:value-of select="date/@time"/>
		<xsl:text> | </xsl:text>
		<xsl:value-of select="$root/meta/author"/>
	</span>

	<xsl:apply-templates select="content/node()" mode="xhtml"/>
</xsl:template>

<xsl:template match="datasource">
<html>
	<head>
		<meta http-equiv="Content-Type" content="text/html; charset=UTF-8"/>
		<meta name="author"      content="{$root/meta/author}"/>
		<meta name="description" content="{$root/meta/description}"/>
		<meta name="viewport"    content="width=device-width,initial-scale=1.0"/>

		<title>
			<xsl:value-of select="$root/meta/title"/>
		</title>

		<link rel="shortcut icon" type="image/x-icon" href="/favicon.ico" />
		<link rel="stylesheet"    type="text/css"     href="/main.css"/>

		<xsl:if test="//*[(self::p or self::span) and @class = 'math']">
			<link rel="stylesheet" type="text/css" href="https://static.kummerlaender.eu/katex/katex.min.css" />
		</xsl:if>
	</head>
	<body>
		<div id="content">
			<div class="large menuhead">
				<h1>
					<xsl:value-of select="$root/meta/title"/>
				</h1>
				<ul>
					<li>
						<a href="https://blog.kummerlaender.eu">blog</a>
					</li>
					<li>
						<a href="https://code.kummerlaender.eu">code</a>
					</li>
					<li>
						<a href="https://tree.kummerlaender.eu">tree</a>
					</li>
				</ul>
			</div>

			<div id="introduction">
				<img src="https://static.kummerlaender.eu/media/me_in_the_mountains_square.jpg"/>
				<p>
					<span class="greeting">Hi there!</span> My name is Adrian Kummerländer and I am a software developer currently studying mathematics in Karlsruhe. On these pages you will find <a href="https://blog.kummerlaender.eu">blog articles</a> covering amongst other topics some of my experiences in software development, open source and related tinkerings as well as <a href="https://code.kummerlaender.eu">repositories</a> and information on some of my personal <a href="https://tree.kummerlaender.eu/projects">projects</a>. If you have any comments or questions feel free to <a href="https://tree.kummerlaender.eu/contact">reach out</a>. I hope you will find something here worth your time.
				</p>
			</div>

			<div class="normal menuhead">
				<h2>
					<a href="https://blog.kummerlaender.eu">
						<xsl:text>Latest articles</xsl:text>
					</a>
				</h2>
				<ul>
					<li>
						<a href="https://blog.kummerlaender.eu/archive">Archive</a>
					</li>
					<li>
						<a href="https://blog.kummerlaender.eu/atom.xml">Feed</a>
					</li>
				</ul>
			</div>

			<xsl:apply-templates select="articles/entry"/>

			<div class="normal menuhead">
				<h2>
					<a href="https://blip.kummerlaender.eu">
						<xsl:text>Selected commits</xsl:text>
					</a>
				</h2>
				<ul>
					<li>
						<a href="https://tree.kummerlaender.eu/projects">Projects</a>
					</li>
					<li>
						<a href="https://blip.kummerlaender.eu/atom.xml">Feed</a>
					</li>
				</ul>
			</div>

			<xsl:apply-templates select="timeline/entry[position() &lt;= $root/meta/limits/blips]"/>
		</div>
	</body>
</html>
</xsl:template>

<xsl:template match="a[@class = 'footnote-ref']" mode="xhtml">
	<xsl:element name="{local-name()}" namespace="http://www.w3.org/1999/xhtml">
		<xsl:copy-of select="@*[name()='id' or name()='class']"/>
		<xsl:attribute name="href">
			<xsl:value-of select="concat(./ancestor::entry/link, '/', ./@href)"/>
		</xsl:attribute>
		<xsl:apply-templates select="node()" mode="xhtml"/>
	</xsl:element>
</xsl:template>

<xsl:template match="text()|@*"/>

</xsl:stylesheet>